#
# file:         p2.gap (split from lielib.gap)
# created:      pasha jan 6 2005
# modified:     
# modification: 
#



# returns p^2-dimensional Poisson Lie algebra in two variables P(2);
# this related with (p^2-2)-dimensional H(2) = SimpleLieAlgebra ("H", [1,1], GF(p)):
# P(2) has one dimensional center, and [P(2)/Z(P(2)),P(2)/Z(P(2))] = H(2).
P2 := function (K)
	local p,T,i,j,k,l;
	
	p := Characteristic (K);
	if p = 0 then
		Error ("the ground field supposed to be of positive characteristic");
	fi;

	T := EmptySCTable (p*p, Zero(K), "antisymmetric");
	# the basis {x^iy^j}, 0 <= i,j <= p-1, is ordered lexicographically by (i,j) 
	# starting from 1 (so x^i y^j is at i + j*p + 1 place) 
	for i in [0..p-1] do
		for j in [0..p-1] do
			for k in [0..p-1] do
				for l in [0..p-1] do
					# this correspond to [x^i y^j, x^k y^l] = (il - jk) x^{i+k-1} y^{j+l-1}
					if i+k > 0 and i+k <= p and j+l > 0 and j+l <= p then
						SetEntrySCTable (T, i + j*p + 1, k + l*p + 1, 
										[i*l - j*k, i+k-1 + (j+l-1)*p + 1]);
					fi;
    			od;
			od;
		od;
	od;
	return (LieAlgebraByStructureConstants (K, T));
end;


# end of p2.gap