#
# file:         deform.gap
# created:      pasha dec 17 2004
# modified:     pasha dec 18 2004
# modification: work in progress
#
# Lie algebra which is simultaneously deformation of current over Witt and Hamiltonian
#

# another approach: 
# 1. be able to define tensor product L\otimes A in gap (done!)
# 2. check the correct behaviour of SimpleLieAlgebra("H") 
# 3. be able to define desired distingished bases in H(2) and W_1(1)\otimes A
# 4. be able to define new Lie algebra by summing structure constants of two given
#    Lie algebras


p := 5;
lambda := 1;

# the basis is ordered lexicographically by (i,j) starting from 1
# (so x^i y^j is at i + j*p + 1 place) 
T := EmptySCTable (p*p, Zero(GF(p)), "antisymmetric");
for i in [0..p-1] do
	for j in [0..p-1] do
		for k in [0..p-1] do
			for l in [0..p-1] do

# this correspond to [x^i y^j, x^k y^l] = (i - k) x^{i+k-1} y^{j+l}
# W(1) \otimes K[y]/(y^p)
#				if i+k > 0 and i+k <= p and j+l >= 0 and j+l < p then
#					SetEntrySCTable (T, i + j*p + 1, k + l*p + 1, 
#									[i-k, i+k-1 + (j+l)*p + 1]);
#				fi;

# this correspond to the "mutual deformation" of H(2) and W(1)\otimes K[y]/(y^p)
# (sum of Lie brackets, H(2) part with coefficient lambda)
				if i+k > 0 and i+k <= p then
					if j+l > 0 and j+l <p then
						# both terms, P(2) and W(1)\otimes K[y]/(y^p), contribution:
						SetEntrySCTable (T, i + j*p + 1, k + l*p + 1, 
										[lambda*(i*l - j*k), i+k-1 + (j+l-1)*p + 1, 
										 i-k,                i+k-1 + (j+l)*p + 1]);
					elif j=0 and l=0 then   # this is equivalent to j+l=0
						# only W(1)\otimes K[y]/(y^p) term contribution:
						SetEntrySCTable (T, i+1, k+1, [i-k, i+k-1 + 1]);
					elif j+l = p then
						# only P(2) contribution
						SetEntrySCTable (T, i + j*p + 1, k + l*p + 1, 
										[lambda*(i*l - j*k), i+k-1 + (j+l-1)*p + 1]);
					fi;
				fi;
    		od;
		od;
	od;
od;

L := LieAlgebraByStructureConstants (GF(p), T);


# end of deform.gap